枫叶/入门

第一章：枫叶入门

开始之前

所有输入给枫叶的命令都在标记为 > 的区域中。
这些是输入区域。
按回车键执行命令。

> sample code;

代码行必须以分号或冒号结尾。注意它们之间的区别

> p - ln( p );

$p-\ln \left(p\right)$

> p - ln (p ):

如果代码行以分号结尾，则验证顺序并软件在输出区域显示答案。如果代码行以冒号结尾，则验证顺序，但答案不显示。

使用枫叶进行简单计算

> (1-1/7)*(1+2/3)^2;

${\frac {50}{21}}$

> (25)^(1/2);

$5\,$

> factorial(15);

$1307674368000\,$

> 15!;

$1307674368000\,$

> sqrt(81);

$9\,$

> sqrt(56.81);

$7.537240874\,$

> %^2;

$56.81\,$

使用枫叶变量

与任何其他编程语言一样，枫叶允许我们将值分配给命名变量。这通常使程序更具可读性，并且它允许我们保存结果以供以后在计算中使用。在这里，2.14 被分配给变量 p。然后我们可以计算 $p-\ln \left(p\right)$ 使 p 评估（替换为）2.14

> p:=2.14;

$p:=2.14\,$

> p - ln(p);

$1.379194171\,$

您也可以在单个表达式中使用多个变量

> x := 2*a-p;

$x:=2\,a-2.14$

> x-sqrt(a*p);

$2\,a-2.14-1.462873884\,{\sqrt {a}}$

> expr := a*x^2 + b*x + c = 0;

$expr:={a{x}}^{2}+bx+c=0\,$

枫叶中操作表达式的命令

枫叶拥有广泛的命令来帮助您操作表达式

> f := (a+b)^6;

$f:=\left(a+b\right)^{6}$

> expand(f);

${a}^{6}+6\,{a}^{5}b+15\,{a}^{4}{b}^{2}+20\,{a}^{3}{b}^{3}+15\,{a}^{2}{b}^{4}+6\,a{b}^{5}+{b}^{6}$

> factor(%);

$\left(a+b\right)^{6}$

> %%;

${a}^{6}+6\,{a}^{5}b+15\,{a}^{4}{b}^{2}+20\,{a}^{3}{b}^{3}+15\,{a}^{2}{b}^{4}+6\,a{b}^{5}+{b}^{6}$

> sin(x)^2+cos(x)^2;

$\left(\sin(x)\right)^{2}+\left(\cos(x)\right)^{2}$

> simplify(%);

$1\,$

这里，%符号表示 Maple 最后一次计算的结果。%%表示倒数第二次计算的结果。%%%表示倒数第三次计算的结果。如果你想查看更早的计算结果，需要将它们分配给变量。

你也可以使用subs命令和带两个参数的eval命令来将表达式中的变量替换为值。

> subs( x=2, x^2+x+1 );

$7\,$

> eval( x^2+x+1,x=2 );

$7\,$

subs命令进行语法替换，

> subs( y=0, sin(y) );

$\sin(0)\,$

而eval命令则进行替换后计算

> eval( sin(y), y=0 );

$0\,$

> eval(f, a=c);

$\left(c+b\right)^{6}$

> eval(f, [a=2, b=4/5]);

${\frac {7529536}{15625}}$

subs命令替换绑定（虚拟）变量，而eval命令不替换。

> subs(x=u,int(f(x),x=0..1) );

$\int _{0}^{1}\!f\left(u\right){du}$

> eval(int(f(x),x=0..1),x=u );

$\int _{0}^{1}\!f\left(x\right){dx}$

eval命令进行同步替换，而subs命令则进行顺序替换。

> subs( x=y, y=x, [x,y] );

$[x,x]\,$

> eval([x,y], {x=y, y=x});

$[y,x]\,$

以下等价：

同步替换

> subs( [x=y, y=x], [x,y] );

$[y,x]\,$

> eval([x,y], {x=y, y=x});

$[y,x]\,$

以及

顺序替换

> subs( x=y, y=x, [x,y] );

$[x,x]\,$

> eval(eval([x,y], x=y), y=x);

$[x,x]\,$

evalf命令计算表达式的浮点数（数值）近似值。你也可以指定所需的精度。

> evalf(sqrt(3));

$1.732050808\,$

> evalf(sqrt(3), 50);

$1.7320508075688772935274463415058723669428052538104\,$

> evalf[50](sqrt(3));

$1.7320508075688772935274463415058723669428052538104\,$

print、lprint和printf命令用于显示数学表达式。print命令使用当前的漂亮打印方法显示表达式。lprint命令以 1D 格式（没有漂亮打印）显示表达式，就像在 Maple 中输入一样。printf命令与 C 或 C++ 语言中使用的相同，你可以在其中使用格式显示变量：%d 表示整数变量，%f 表示浮点数，\n 表示换行符。

> f:=a-3/a+1/(a*a+1);

$f:=a-{\frac {3}{a}}+{\frac {1}{{a}^{2}+1}}$

> print(f);

$a-{\frac {3}{a}}+{\frac {1}{{a}^{2}+1}}$

> lprint(f);

a-3/a+1/(a^2+1)

> printf("%d %f \n",123,1234/567); 

123 2.176367

使用 Maple 定义函数

定义函数的最简单形式是使用箭头（映射）运算符 ->

> f := t -> sin(t) - t;

$f:=t\rightarrow \sin(t)-t$

> f(3*x + 2);

$\sin(3\,x+2)-3\,x-2$

注意

> f := x->2*x+2;

定义 f 作为函数，即

> f(u);

$2u+2\,$

> f(x):=2*x+2;

定义 f 作为带有“记忆表”的过程，该表仅针对参数 x：

> f(u);

$\mathrm {f} (u)\,$

以及

> f(x)=2*x+2;

是一个方程。

使用 Maple 进行微积分

可以使用 diff 命令对表达式进行求导

> diff(f(t), t);

可以将多个偏导数作为列表给出。要对 g 相对于 u 然后相对于 v 求导，可以使用以下命令

> diff(g(u,v,w), [u,v]);

Maple 也可以使用 D 运算符对函数进行求导

> D(f);

如果函数有多个变量，可以将变量指定为索引

> D[1](g);

注意 diff 和 D 之间的区别：diff 对表达式进行操作，并返回一个表达式，而 D 对函数进行操作，并返回另一个函数。

Maple 可用于查找表达式的原函数、不定积分或反导数。例如，要获得 f(t) 函数关于 t 的不定积分和 g(u,v,w) 函数关于 v 的不定积分，可以输入以下命令

> Int(f(t), t) = int(f(t), t);

$\int \left(\sin(t)-t\right)\,dt=-\cos(t)-{\frac {1}{2}}\,{t}^{2}$

> Int(g(u,v,w), v) = int(g(u,v,w), v);

$\int \left({\frac {1}{u}}+e^{u+v}+(u-v+w)^{2}\right)\,{dv}={\frac {v}{u}}+{e^{u+v}}-{\frac {1}{3}}(u-v+w)^{3}$

注意 Int 和 int 命令之间的区别。前者是惰性形式，它只显示积分。后者是活动形式，并计算其值。

Maple 也可以计算定积分

> Int(f(t),t=0..Pi)=int(f(t),t=0..Pi);

$\int _{0}^{\pi }\left(\sin(t)-t\right)\,dt=2-{\frac {1}{2}}\pi ^{2}$

要计算惰性积分，可以使用 value 命令

> value(Int(f(t), t));

$-\cos(t)-{\frac {1}{2}}\,{t}^{2}$

惰性形式的另一个用途是对定积分进行数值逼近

> evalf(Int(f(t),t=0..Pi));

$1.57079633$

这应该与 evalf(int(f(t), t=0..Pi)) 给出相同的答案，但计算方式不同。当使用积分的惰性形式时，Maple 会使用定积分的定义来计算曲线下方区域的近似值。然后，当使用 int 形式时，将计算定积分的精确值，然后对该值进行数值逼近。使用惰性形式直接计算逼近值对于大型问题可能快得多。

使用 Maple 进行求极限、求和和求积

您还可以分别使用 sum、limit 和 product 函数找到和、极限和积的数值和符号值

> limit((2*t-3)/(3*t+4),t=infinity);

${\frac {2}{3}}$

> limit((2*t-3)/(3*t+4),t=-4/3,right); #right-bound of the limit

$-\infty$

> Sum(i^2,i=1..10)=sum(i^2,i=1..10);

$\sum _{i=1}^{10}i^{2}=385$

> Product(1/i,i=1..10)=product(1/i,i=1..10);

$\prod _{i=1}^{10}{\frac {1}{i}}={\frac {1}{3628800}}$

命令 Sum 和 Product 是惰性的，它们实际上并不计算求和或乘积。

用 Maple 求解方程

函数 solve(eqn,x) 尝试在 eqn 中找到 x 的值。您还可以使用更多变量或更多方程，使用 solve({eqn1,eqn2,...},{x,y,...}):

> solve(2*t+3=-t+6*sqrt(2));

$-1+2{\sqrt {2}}$

> solve(t-15/4*u=5/2*(u-t)+3,u);

${\frac {14}{25}}t-{12}{25}$

> solve({a-b=2,a+3*b=7},{a,b});

$\left\{a={\frac {13}{4}},b={\frac {5}{4}}\right\}$

有时，可能无法找到方程的精确解。然后您可以使用 fsolve() 获取数值近似值

> fsolve(cos(t)=t);

$0.7390851332$

> fsolve({t^3+u=1,u-(t-1)^3=t},{t,u});

$\{t=0.6941457205,u=0.6655340191\}$

为解命名

解可以存储在一个变量中，就像任何其他表达式一样

> solution := solve({a-b = x, a+b = 1/x}, {a, b});

$solution:=\left\{b=-{\frac {1}{2}}{\frac {x^{2}-1}{x}},~a={\frac {1}{2}}{\frac {x^{2}+1}{x}}\right\}$

在示例中，变量 solution 被分配了值，然后可以在后续计算中使用。有时，值得将解的一部分保留在独立变量中。这可以通过适当的替换来完成。为了能够复制微积分的每一步，最好不要替换用于编写原始方程的变量 (a,b)，而是创建新的名称，例如，solutiona" 和 "solutionb":

> solutiona := eval(a, solution)

$solutiona:={\frac {1}{2}}{\frac {x^{2}+1}{x}}$

> solutionb := eval(b, solution)

$solutionb:=-{\frac {1}{2}}{\frac {x^{2}-1}{x}}$

然后，可以通过一些图或未来的计算中的标识符访问这些表达式。

用 Maple 绘制函数

要绘制函数 f(x)，请使用命令 plot(f(x),x)

> plot(sin(t)/t,t=-20..20,title="function t ---> sin t / t");

> plot3d(x*exp(-x^2-y^2),x=-2..2,y=-2..2,color=x,orientation=[120,75]);