OpenSCAD 用户手册/类型测试函数

is_undef

[注意：需要版本 2019.05]

is_undef 接受一个参数。如果参数未定义，此函数返回 true。如果参数未定义，则返回 false。当检查变量（如 `is_undef(a)`）时，它会静默地执行变量查找，这意味着 is_undef(a) 不会导致 `WARNING: Ignoring unknown variable 'a'.`

另一种方法是使用以下代码

if(a==undef){
    //code goes here
}

或者

b = (a==undef) ? true : false;

会导致

WARNING: Ignoring unknown variable 'a'.

is_undef 也适用于特殊变量，允许进行以下操作

exploded = is_undef($exploded) ? 0 : $exploded; // 1 for exploded view

遗留支持

对于旧版本的 openscad，可以使用以下方法模拟 is_undef

function is_undef ( a ) = (undef == a) ;

这当然会导致警告，但不需要更改依赖于 is_undef() 的代码。

is_list

[注意：需要版本 2019.05]

echo("returning true");
echo(is_list([]));
echo(is_list([1]));
echo(is_list([1,2]));
echo(is_list([true]));
echo(is_list([1,2,[5,6],"test"]));
echo("--------");
echo("returning false");
echo(is_list(1));
echo(is_list(1/0));
echo(is_list(((1/0)/(1/0))));
echo(is_list("test"));
echo(is_list(true));
echo(is_list(false));
echo("--------");
echo("causing warnings:");
echo(is_list());
echo(is_list(1,2));

is_num

[注意：需要版本 2019.05]

echo("a number is a number:");
echo(is_num(0.1));
echo(is_num(1));
echo(is_num(10));

echo("inf is a number:");
echo(is_num(+1/0)); //+inf
echo(is_num(-1/0)); //-inf

echo("nan is not a number:");
echo(is_num(0/0)); //nan
echo(is_num((1/0)/(1/0)));  //nan

echo("resulting in false:");
echo(is_num([]));
echo(is_num([1]));
echo(is_num("test"));
echo(is_num(false));
echo(is_num(undef));

is_bool

[注意：需要版本 2019.05]

echo("resulting in true:");
echo(is_bool(true));
echo(is_bool(false));
echo("resulting in false:");
echo(is_bool([]));
echo(is_bool([1]));
echo(is_bool("test"));
echo(is_bool(0.1));
echo(is_bool(1));
echo(is_bool(10));
echo(is_bool(0/0)); //nan
echo(is_bool((1/0)/(1/0)));  //nan
echo(is_bool(1/0));  //inf
echo(is_bool(-1/0));  //-inf
echo(is_bool(undef));

is_string

[注意：需要版本 2019.05]

echo("resulting in true:");
echo(is_string(""));
echo(is_string("test"));
echo("resulting in false:");
echo(is_string(0.1));
echo(is_string(1));
echo(is_string(10));
echo(is_string([]));
echo(is_string([1]));
echo(is_string(false));
echo(is_string(0/0)); //nan
echo(is_string((1/0)/(1/0)));  //nan
echo(is_string(1/0));  //inf
echo(is_string(-1/0));  //-inf
echo(is_string(undef));

is_function

[注意：需要版本 2021.01]

is_function 检查仅适用于表达式，因此它可以应用于函数文字或包含函数的变量。它不适用于内置函数或普通函数定义。

echo(is_function(function(x) x*x)); // ECHO: true

func = function(x) x+x;
echo(is_function(func)); // ECHO: true

function f(x) = x;
echo(is_function(f)); // WARNING: Ignoring unknown variable 'f' / ECHO: false