用法

FOR 'word start end bump body

描述

在一定范围的值上重复一个代码块。

FOR 是一个函数值。

参数

word -- 用于保存当前值的变量 (类型：词语)
start -- 起始值 (类型：数字序列货币时间日期字符)
end -- 结束值 (类型：数字序列货币时间日期字符)
bump -- 每次跳过的数量 (类型：数字货币时间字符)
body -- 要执行的代码块 (类型：代码块)

(特殊属性)

捕获
抛出

源代码

for: func [
    "Repeats a block over a range of values." 
    [catch throw] 
    'word [word!] "Variable to hold current value" 
    start [number! series! money! time! date! char!] "Starting value" 
    end [number! series! money! time! date! char!] "Ending value" 
    bump [number! money! time! char!] "Amount to skip each time" 
    body [block!] "Block to evaluate" 
    /local result do-body op
][
    if (type? start) <> (type? end) [
        throw make error! reduce ['script 'expect-arg 'for 'end type? start]
    ] 
    do-body: func reduce [[throw] word] body 
    op: :greater-or-equal? 
    either series? start [
        if not same? head start head end [
            throw make error! reduce ['script 'invalid-arg end]
        ] 
        if (negative? bump) [op: :lesser?] 
        while [op index? end index? start] [
            set/any 'result do-body start 
            start: skip start bump
        ] 
        if (negative? bump) [set/any 'result do-body start]
    ] [
        if (negative? bump) [op: :lesser-or-equal?] 
        while [op end start] [
            set/any 'result do-body start 
            start: start + bump
        ]
    ] 
    get/any 'result
]