Ring/Lessons/自然语言编程

自然语言编程

使用 Ring 编程语言，我们可以基于类和对象创建自然编程语言。

历史

2010年，我开发了一种名为 Supernova 的新编程语言（使用 PWCT 开发）。这种语言使用类似于自然语言语句的代码来创建简单的 GUI 应用程序。现在，五年后，在 Ring 编程语言中，我们可以获得类似的结果，但现在我们能够在任何我们喜欢或需要的领域创建/使用类似于自然语言语句的代码。

Ring 编程语言附带 Supernova sprite，但具有更强的通用性和其他语言 sprite 的混合。

示例

以下示例演示如何创建一个定义两个指令的类

第一个指令是：我要窗口

第二个指令是：窗口标题 = <expr>

还有可以忽略的关键字，例如“the”关键字

	New App 
	{
		I want window 	
		The window title = "hello world"
	}

	Class App

		# Attributes for the instruction I want window
				i want window 
				nIwantwindow = 0
		# Attributes for the instruction Window title
		# Here we don't define the window attribute again
				title 
				nWindowTitle = 0
		# Keywords to ignore, just give them any value
				the=0	

		func geti
			if nIwantwindow = 0
				nIwantwindow++
			ok

		func getwant
			if nIwantwindow = 1
				nIwantwindow++
			ok

		func getwindow
			if nIwantwindow = 2
				nIwantwindow= 0
				see "Instruction : I want window" + nl
			ok
			if nWindowTitle = 0
				nWindowTitle++
			ok
	
		func settitle cValue
			if nWindowTitle = 1
				nWindowTitle=0
				see "Instruction : Window Title = " + cValue + nl
			ok

输出

	Instruction : I want window
	Instruction : Window Title = hello world