XQuery/SPARQL 教程

SPARQL 接口

可以使用 SPARQL 通过 XQuery 前端查询 emp-dept RDF，该前端连接到存储，该存储由 Talis 提供。此脚本支持 SPARQL 查询和浏览 RDF 图。

该接口扩展了查询，例如

  select ?name ?job where {
   ?emp rdf:type  f:emp.
   ?emp foaf:surname ?name.
   ?emp f:Job ?job.
  }

你可以在这里 ^{[失效链接]} 运行

 prefix foaf: <http://xmlns.com/foaf/0.1/>
 prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
 prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
 prefix f: <http://www.cems.uwe.ac.uk/empdept/concept/>
 prefix xs: <http://www.w3.org/2001/XMLSchema#>
 select ?name ?job 
  where {
   ?emp rdf:type  f:emp.
   ?emp foaf:surname ?name.
   ?emp f:Job ?job.
 }

并将此发送到 Talis 服务，以一种可以运行的形式，你可以在这里运行。由此产生的 SPARQLQuery Results XML 将被转换为 HTML。

示例查询

列出所有员工

 select ?emp where {
  ?emp  rdf:type  f:emp.
 }

运行 ^{[失效链接]}

按字母顺序列出所有员工姓名

 select ?name where {
  ?emp  rdf:type  f:emp.
  ?emp  foaf:surname ?name. 
 }
 ORDER BY ?name

运行 ^{[失效链接]}

列出员工的姓名、薪水、部门编号和职位

 select ?name ?sal ?dno ?job where {
  ?emp  rdf:type  f:emp;
        foaf:surname ?name;
        f:Sal ?sal;
        f:Dept ?dept;
        f:Job ?job.  
  ?dept f:DeptNo ?dno. 
 }

注意，; 代替 . 重复主题。

在这里 ^{[失效链接]} 尝试此查询和以下查询。

列出前 5 位员工

select ?ename where {
  ?emp  rdf:type  f:emp;
        foaf:surname ?ename.
} 
ORDER BY ?ename
LIMIT 5

按薪水列出前 5 位员工

select ?ename ?sal where {
 ?emp  rdf:type  f:emp;
       foaf:surname ?ename;
       f:Sal ?sal.
} 
ORDER BY DESC(?sal)
LIMIT 5

列出部门

select ?dept where {
  ?dept  rdf:type  f:dept.  
}

列出所有部门和所有员工

select ?dept ?emp where {
  {?dept  rdf:type  f:dept }
  UNION
  {?emp rdf:type f:emp}
}

列出薪水超过 1000 的员工

如果 RDF 文字被类型化，例如，作为 xs:integer，就像此生成的 RDF 中一样，那么以下查询将选择薪水大于 1000 的员工

select ?emp ?sal where {
  ?emp  rdf:type  f:emp;
        f:Sal ?sal.
  FILTER (?sal > 1000)
}

如果 RDF 文字未被类型化，则必须转换变量

 select ?emp ?sal where {
  ?emp  rdf:type  f:emp;
        f:Sal ?sal.
  FILTER (xs:integer(?sal) > 1000)
}

列出员工及其工作地点

select ?emp ?loc where {
  ?emp  rdf:type  f:emp.
  ?emp f:Dept ?dept.
  ?dept f:Location ?loc.
}

列出员工姓名及其经理

select ?ename ?mname where {
  ?emp  rdf:type  f:emp;
        f:Mgr ?mgr;
        foaf:surname ?ename.
  ?mgr foaf:surname ?mname.
}

包含没有经理的员工

select ?ename ?mname where {
  ?emp  rdf:type  f:emp;
        foaf:surname ?ename.
  OPTIONAL {?emp f:Mgr ?mgr.
            ?mgr foaf:surname ?mname.
           }
}

列出没有经理的员工

select ?ename where {
  ?emp  rdf:type  f:emp;
        foaf:surname ?ename.
  OPTIONAL {?emp f:Mgr ?mgr}
  FILTER (!bound(?mgr))
}

列出员工的不同位置

select distinct ?loc  where {
  ?emp  rdf:type  f:emp.
  ?emp  f:Dept ?dept.
  ?dept f:Location ?loc.
}

列出担任分析师的员工的详细信息

select * where {
  ?emp  rdf:type  f:emp.
  ?emp  f:Dept ?dept.
  ?dept f:Location ?loc.
  ?emp f:Job ?job.
  FILTER (?job = "ANALYST")
}

列出担任分析师或经理的员工

select ?emp where {
  ?emp  rdf:type  f:emp;
        f:Job ?job.
  FILTER (?job = "ANALYST"  || ?job = "MANAGER")
}

列出既不是分析师也不是经理的员工

select * where {
   ?emp  rdf:type  f:emp;
         f:Job ?job.
   FILTER (?job != "ANALYST"  && ?job != "MANAGER")
}

列出姓氏以“S”开头的员工

select * where {
  ?emp  rdf:type  f:emp.
  ?emp foaf:surname ?ename.
  FILTER (regex(?ename, "^S"))
}

列出姓氏包含“AR”的员工

select * where {
  ?emp  rdf:type  f:emp.
  ?emp foaf:surname ?ename.
  FILTER (regex(?ename, "AR"))
}

列出姓氏包含“M”后跟“R”的员工，不区分大小写

select * where {
  ?emp  rdf:type  f:emp.
  ?emp foaf:surname ?ename.
  FILTER (regex(?ename, "m.*r","i"))
}

计算最高薪水

SPARQL 1.0 缺少 min() 或 max()，虽然它们已添加到一些实现中。以下方法，由 Dean Allemang 提供，可以用来计算最高薪水

select ?maxemp ?maxsal where {
 ?maxemp  rdf:type  f:emp.
 ?maxemp  f:Sal ?maxsal.
 OPTIONAL { ?emp rdf:type f:emp.
            ?emp f:Sal ?sal.
            FILTER ( ?sal > ?maxsal)
          }.
 FILTER (!bound (?sal))
}

它是如何工作的？我们想要找到最高员工的最高薪水。对于这样的员工，OPTIONAL 子句将不匹配，因为没有薪水更高的员工，因此 ?sal 将不会绑定。

在 SPARQL 1.1 中，允许使用 max() 和 min()，因此返回最高薪水的查询变为

select (max(?sal) as ?maxsal) where {
  ?maxemp  rdf:type  f:emp.
  ?maxemp  f:Sal ?sal.
}

计算薪水相同的员工

 select * where {
    ?emp1 f:Sal ?sal.
    ?emp2 f:Sal ?sal.
    FILTER (?emp1 != ?emp2)
 }

获取 SMITH 所属的部门

select ?dname  where {
  ?emp  rdf:type  f:emp.
  ?emp f:Dept ?dept.
  ?emp foaf:surname "SMITH".
  ?dept f:Dname ?dname.
}

列出会计部门员工的姓名

select ?ename  where {
  ?emp  rdf:type  f:emp.
  ?emp f:Dept ?dept.
  ?emp foaf:surname ?ename.
  ?dept f:Dname "Accounting".
}

本世纪录用的员工

select ?ename ?hire where {
 ?emp  rdf:type  f:emp.
 ?emp f:HireDate ?hire.
 ?emp foaf:surname ?ename.
 FILTER (?hire > "2000-01-01"^^xs:date) 
}

请注意，字面量需要类型化才能使比较有效。

列出经理在不同部门的员工的姓名

select ?name ?edname ?mdname {
  ?emp  rdf:type  f:emp;
        foaf:surname ?name;
        f:Dept ?dept;
        f:Mgr ?mgr.
  
   ?mgr f:Dept ?mdept. 
   ?dept f:Dname ?edname.
   ?mdept f:Dname ?mdname.
   FILTER (?dept != ?mdept)
}

列出员工的等级

从关系的角度来看，这是员工表和 salgrade 表之间的 theta 连接。

select ?ename ?grade where {
 ?emp  rdf:type  f:emp;
       foaf:surname ?ename;
       f:Sal ?sal.
 ?salgrade rdf:type f:salgrade; 
       f:LoSal ?low; 
       f:HiSal ?high;
       f:Grade ?grade.
   
 FILTER (?sal >= ?low && ?sal <= ?high)
 }

简化的查询语法

一个新的前缀简化了通过其 URI 引用单个资源。

 prefix e: <http://www.cems.uwe.ac.uk/empdept/emp/>
 select ?sal  where {
    e:7900 f:Sal ?sal.
 }

是

 select ?sal  where {
    <http://www.cems.uwe.ac.uk/empdept/emp/7900> f:Sal ?sal.
 }

的简写。

prefix : <http://www.cems.uwe.ac.uk/empdept/concept/>
select ?name ?sal ?dno ?job where {
 ?emp  rdf:type  :emp;
       foaf:surname ?name;
       :Sal ?sal;
       :Dept ?dept;
       :Job ?job.  
 ?dept :DeptNo ?dno. 
}

我们还可以引入一个默认命名空间

prefix : <http://www.cems.uwe.ac.uk/empdept/concept/>
select ?name ?sal ?dno ?job where {
 ?emp  a :emp;
       foaf:surname ?name;
       :Sal ?sal;
       :Dept ?dept;
       :Job ?job.  
 ?dept :DeptNo ?dno. 
}

并使用缩写a表示 rdf:type

prefix : <http://www.cems.uwe.ac.uk/empdept/concept/>
select ?name ?sal ?dno ?job where {
 [ a :emp;
   foaf:surname ?name;
   :Sal ?sal;
   :Dept ?dept;
   :Job ?job
 ].
 ?dept :DeptNo ?dno. 
}

如果我们不需要返回资源本身，它可以是匿名的

[编辑 | 编辑源代码]

虽然 count() 和 sum() 等聚合函数和 GROUP BY 子句在 SPARQL 1.0 中没有定义，但它们在一些服务（例如 Talis 平台）上是可用的，在 SPARQL 1.1 标准化之前。

select (count(?dept) as ?count) where {
  ?dept  rdf:type  f:dept.

}

[编辑 | 编辑源代码]

select distinct ?dept (count(?emp) as ?count) where {
  ?dept a f:dept.
  ?emp f:Dept ?dept.
} group by ?dept

[编辑 | 编辑源代码]

三元组数据模型的统一性使我们能够以非常通用的方式查询数据集，如果我们对数据一无所知，这将非常有用。

select * where {
 ?s ?p ?o
}

[编辑 | 编辑源代码]

select * where {
 ?s ?p ?o
} LIMIT 20

这在现实数据集上是不可行的，但可以通过限制返回的三元组数量来获取三元组样本。

select ?prop ?val where {
  ?emp  rdf:type  f:emp.
  ?emp ?prop ?val.
}

[编辑 | 编辑源代码]

select distinct ?type where {
  ?s a ?type
}

这表明定义 emp 词汇表的三个元组在同一个数据集中。

有哪些属性？

select distinct ?prop where {
   ?s ?prop ?o
}

属性的域是什么？

select distinct ?type where {
    ?s f:Sal ?v.
    ?s a ?type.
}

属性的范围是什么？

select distinct ?type where {
    ?s f:Sal ?o.
    ?o a ?type.
}

此查询仅查找作为数据集中类型实例的范围。Sal 的范围是 xs:integer，但很难用 SPARQL 查询发现这一点。

select distinct ?type where {
    ?s f:Mgr ?o.
    ?o a ?type.
}

哪些属性的域是给定的类型？

select distinct ?prop where {
     ?s a f:salgrade.
     ?s ?prop [].
}

模式查询

模式数据的出现使 SPARQL 可以用来查询此元数据。可以将结果与通过直接查询数据获得的结果进行比较。

哪些属性的域是给定的类型？

select ?prop  where {
   ?prop rdfs:domain f:emp.
}

请注意，这只会返回 empdept 词汇表中的属性，而不是原始数据中使用的 foaf name 属性。

员工有哪些整数属性？

select ?prop  where {
   ?prop rdfs:domain f:emp.
   ?prop rdfs:range xs:integer.
}

哪些类型的资源有工资？

select ?type where {
  f:Sal rdfs:domain ?type.
}

可以对数据和词汇表进行查询

经理有哪些文字属性？

select DISTINCT ?prop  where {
   ?x f:Job "MANAGER".
   ?x a ?type. 
   ?prop rdfs:domain ?type.
   ?prop rdfs:range rdfs:literal.
}

待办事项

示例 RDF 缺少语言标签，这些标签是演示 lang() 函数所必需的
所有查询将与 SQL 和 XQuery 等效项一起移至代码列表