Cg 编程/Unity/镜面高光
本教程涵盖逐顶点光照（也称为古罗德着色），使用冯氏反射模型。
它扩展了“漫反射”章节中的着色器代码，增加了两个额外项：环境光照和镜面反射。这三个项共同构成了冯氏反射模型。如果您尚未阅读“漫反射”章节，现在是一个很好的机会阅读它。
仔细观察卡拉瓦乔左侧的画作。虽然白色衬衫的大部分区域都处于阴影中，但没有部分是完全黑色的。显然，总会有一些光线从墙壁和其他物体反射出来，照亮场景中的所有东西——至少在一定程度上。在冯氏反射模型中，这种效果通过环境光照来考虑，它取决于一般环境光强度 和漫反射的材料颜色。在环境光照强度 的方程式中
类似于“漫反射”章节中漫反射方程式，此方程式也可以解释为光的红色、绿色和蓝色分量的向量方程式。
在 Unity 中，通过从主菜单中选择窗口 > 渲染 > 光照设置，将场景 > 环境光照 > 源设置为颜色并指定环境颜色来指定统一的环境光。在 Unity 中的 Cg 着色器中，此颜色可作为UNITY_LIGHTMODEL_AMBIENT使用，它是“世界空间着色”章节中提到的预定义制服之一。（如果您选择渐变而不是颜色，则UNITY_LIGHTMODEL_AMBIENT和unity_AmbientSky指定天空颜色，而赤道颜色和地面颜色则分别由unity_AmbientEquator和unity_AmbientGround指定。）
如果您仔细观察卡拉瓦乔的画作，您会看到几个镜面高光：在鼻子、头发、嘴唇、鲁特琴、小提琴、弓、水果等。冯氏反射模型包含一个镜面反射项，可以模拟这种光滑表面上的高光；它甚至包含一个参数 来指定材料的光泽度。光泽度指定高光的大小：光泽度越高，高光越小。
一个完美光滑的表面只会反射来自光源的光线，其方向为几何反射方向R。对于光泽度低于完美的表面，光线会反射到R周围的方向：光泽度越低，扩散越广。在数学上，规范化的反射方向R 由
定义，其中N 是规范化的表面法向量，L 是规范化的光源方向。在 Cg 中，函数float3 reflect(float3 I, float3 N)（或float4 reflect(float4 I, float4 N)）计算相同的反射向量，但针对从光源到表面上的点的方向I。因此，我们必须将L取反以使用此函数。
镜面反射项计算观察者方向V 的镜面反射。如上所述，如果V 接近R，则强度应该很大，其中“接近”由光泽度 参数化。在冯氏反射模型中，R 和V 之间角度的余弦的 次方用于生成不同光泽度的亮点。与漫反射的情况类似，我们应该将负余弦值钳制为 0。此外，镜面项需要材料颜色 用于镜面反射，它通常只是白色，这样所有亮点都具有入射光 的颜色。例如，卡拉瓦乔画作中的所有亮点都是白色的。冯氏反射模型的镜面项为
类似于漫反射的情况，如果光源位于表面的“错误”一侧，则应忽略镜面反射项；即如果点积 N·L 为负。
着色器代码
[edit | edit source]环境光照的着色器代码很简单，使用逐分量向量-向量乘积
float3 ambientLighting =
UNITY_LIGHTMODEL_AMBIENT.rgb * _Color.rgb;
为了实现镜面反射，我们需要在世界空间中获得观察者的方向，我们可以将其计算为相机位置和顶点位置之间的差值（都在世界空间中）。世界空间中的相机位置由 Unity 在 uniform _WorldSpaceCameraPos 中提供；顶点位置可以按照“漫反射”部分所述转换为世界空间。然后可以像这样实现世界空间中镜面反射项的方程式
float3 viewDirection = normalize(_WorldSpaceCameraPos
- mul(modelMatrix, input.vertex).xyz);
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
此代码片段使用与“漫反射”部分着色器代码相同的变量，以及用户指定的属性 _SpecColor 和 _Shininess。（这些名称是专门选择的，以便回退着色器可以访问它们；请参阅“漫反射”部分的讨论。）pow(a, b) 计算 .
如果环境光照被添加到第一遍（我们只需要它一次），并且镜面反射被添加到“漫反射”部分的完整着色器的两遍，它看起来像这样
Shader "Cg per-vertex lighting" {
Properties {
_Color ("Diffuse Material Color", Color) = (1,1,1,1)
_SpecColor ("Specular Material Color", Color) = (1,1,1,1)
_Shininess ("Shininess", Float) = 10
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
// pass for ambient light and first light source
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 col : COLOR;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float3x3 modelMatrixInverse = unity_WorldToObject;
float3 normalDirection = normalize(
mul(input.normal, modelMatrixInverse));
float3 viewDirection = normalize(_WorldSpaceCameraPos
- mul(modelMatrix, input.vertex).xyz);
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource = _WorldSpaceLightPos0.xyz
- mul(modelMatrix, input.vertex).xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
float3 ambientLighting =
UNITY_LIGHTMODEL_AMBIENT.rgb * _Color.rgb;
float3 diffuseReflection =
attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
output.col = float4(ambientLighting + diffuseReflection
+ specularReflection, 1.0);
output.pos = UnityObjectToClipPos(input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
return input.col;
}
ENDCG
}
Pass {
Tags { "LightMode" = "ForwardAdd" }
// pass for additional light sources
Blend One One // additive blending
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 col : COLOR;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float3x3 modelMatrixInverse = unity_WorldToObject;
float3 normalDirection = normalize(
mul(input.normal, modelMatrixInverse));
float3 viewDirection = normalize(_WorldSpaceCameraPos
- mul(modelMatrix, input.vertex).xyz);
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource = _WorldSpaceLightPos0.xyz
- mul(modelMatrix, input.vertex).xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
float3 diffuseReflection =
attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
output.col = float4(diffuseReflection
+ specularReflection, 1.0);
// no ambient contribution in this pass
output.pos = UnityObjectToClipPos(input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
return input.col;
}
ENDCG
}
}
Fallback "Specular"
}
总结
[edit | edit source]恭喜，您刚刚学习了如何实现 Phong 反射模型。具体来说，我们已经看到了
- Phong 反射模型中的环境光照是什么。
- Phong 反射模型中的镜面反射项是什么。
- 如何在 Unity 中使用 Cg 实现这些项。
进一步阅读
[edit | edit source]如果您还想了解更多
- 关于着色器代码，您应该阅读“漫反射”部分。