跳转到内容

GLSL 编程/GLUT/光泽纹理

Add links
来自 Wikibooks，开放世界中的开放书籍
从国际空间站 (ISS) 看太平洋上空的日落，带有镜面反射。

本教程涵盖了部分光泽、纹理表面的逐像素光照。

它结合了纹理球体教程和平滑镜面反射教程的着色器代码，以计算逐像素光照，并使用纹理的 RGB 分量确定漫反射的材质颜色，并使用同一纹理的 A 分量确定镜面反射的强度。如果您还没有阅读纹理球体教程或平滑镜面反射教程，现在是一个非常好的机会去阅读它们。

光泽映射

[编辑 | 编辑源代码]

光照纹理表面教程介绍了使用纹理图像的 RGB 分量确定漫反射材质常数的概念。在这里，我们扩展了这种技术，并使用同一纹理图像的 A（alpha）分量来确定镜面反射的强度。仅使用一个纹理提供了显着的性能优势，特别是在某些情况下，RGBA 纹理查找与 RGB 纹理查找一样昂贵。

如果纹理图像的“光泽”（即镜面反射的强度）编码在 RGBA 纹理图像的 A（alpha）分量中，我们可以简单地将镜面反射的材质常数乘以纹理图像的 alpha 分量。是在镜面反射教程中引入的，并出现在 Phong 反射模型的镜面反射项中

如果乘以纹理图像的 alpha 分量，该项将达到其最大值（即表面是光泽的），其中 alpha 为 1，并且它为 0（即表面根本不光泽），其中 alpha 为 0。

带有透明水的地球地图，即水面的 alpha 分量为 0，陆地的 alpha 分量为 1。

逐像素光照的着色器代码

[编辑 | 编辑源代码]

着色器代码是平滑镜面反射教程中的逐像素光照和纹理球体教程中的纹理的组合。类似于光照纹理表面教程，textureColor中的纹理颜色的 RGB 分量乘以环境光和漫反射光。

在左侧的特定纹理图像中，水的 alpha 分量为 0，陆地的 alpha 分量为 1。但是，应该是水是光泽的，而陆地不是。因此，对于这个特定的图像，我们应该将镜面材质颜色乘以(1.0 - textureColor.a)。另一方面，通常的光泽贴图需要乘以textureColor.a。（注意，对着色器程序进行这种更改是多么容易。）

顶点着色器是

attribute vec3 v_coord;
attribute vec3 v_normal;
varying vec4 position;  // position of the vertex (and fragment) in world space
varying vec3 varyingNormalDirection;  // surface normal vector in world space
varying vec4 texCoords; // the texture coordinates
uniform mat4 m, v, p;
uniform mat3 m_3x3_inv_transp;

void main()
{
  vec4 v_coord4 = vec4(v_coord, 1.0);
  mat4 mvp = p*v*m;
  position = m * v_coord4;
  varyingNormalDirection = normalize(m_3x3_inv_transp * v_normal);

  texCoords = v_coord4;
  gl_Position = mvp * v_coord4;
}

片段着色器变为

varying vec4 position;  // position of the vertex (and fragment) in world space
varying vec3 varyingNormalDirection;  // surface normal vector in world space
varying vec4 texCoords; // the texture coordinates
uniform mat4 m, v, p;
uniform mat4 v_inv;
uniform sampler2D mytexture;
 
struct lightSource
{
  vec4 position;
  vec4 diffuse;
  vec4 specular;
  float constantAttenuation, linearAttenuation, quadraticAttenuation;
  float spotCutoff, spotExponent;
  vec3 spotDirection;
};
lightSource light0 = lightSource(
  vec4(0.0,  1.0,  0.0, 1.0),
  vec4(1.0,  1.0,  1.0, 1.0),
  vec4(1.0,  1.0,  1.0, 1.0),
  0.0, 1.0, 0.0,
  180.0, 0.0,
  vec3(0.0, 0.0, 0.0)
);
vec4 scene_ambient = vec4(0.2, 0.2, 0.2, 1.0);

struct material
{
  vec4 ambient;
  vec4 diffuse;
  vec4 specular;
  float shininess;
};
material frontMaterial = material(
  vec4(0.2, 0.2, 0.2, 1.0),
  vec4(1.0, 0.8, 0.8, 1.0),
  vec4(1.0, 1.0, 1.0, 1.0),
  5.0
);
 
void main()
{
  vec3 normalDirection = normalize(varyingNormalDirection);
  vec3 viewDirection = normalize(vec3(v_inv * vec4(0.0, 0.0, 0.0, 1.0) - position));
  vec3 lightDirection;
  float attenuation;

  vec2 longitudeLatitude = vec2((atan(texCoords.y, texCoords.x) / 3.1415926 + 1.0) * 0.5,
                                (asin(texCoords.z) / 3.1415926 + 0.5));
  // unusual processing of texture coordinates
  
  vec4 textureColor = texture2D(mytexture, longitudeLatitude);
 
  if (0.0 == light0.position.w) // directional light?
    {
      attenuation = 1.0; // no attenuation
      lightDirection = normalize(vec3(light0.position));
    } 
  else // point light or spotlight (or other kind of light) 
    {
      vec3 positionToLightSource = vec3(light0.position - position);
      float distance = length(positionToLightSource);
      lightDirection = normalize(positionToLightSource);
      attenuation = 1.0 / (light0.constantAttenuation
                           + light0.linearAttenuation * distance
                           + light0.quadraticAttenuation * distance * distance);
 
      if (light0.spotCutoff <= 90.0) // spotlight?
        {
          float clampedCosine = max(0.0, dot(-lightDirection, light0.spotDirection));
          if (clampedCosine < cos(radians(light0.spotCutoff))) // outside of spotlight cone?
            {
              attenuation = 0.0;
            }
          else
            {
              attenuation = attenuation * pow(clampedCosine, light0.spotExponent);   
            }
        }
    }
 
  vec3 ambientLighting = vec3(scene_ambient) * vec3(textureColor);
 
  vec3 diffuseReflection = attenuation 
    * vec3(light0.diffuse) * vec3(textureColor)
    * max(0.0, dot(normalDirection, lightDirection));
 
  vec3 specularReflection;
  if (dot(normalDirection, lightDirection) < 0.0) // light source on the wrong side?
    {
      specularReflection = vec3(0.0, 0.0, 0.0); // no specular reflection
    }
  else // light source on the right side
    {
        specularReflection = attenuation * vec3(light0.specular) * vec3(frontMaterial.specular) * (1.0 - textureColor.a)
          // for usual gloss maps: "* textureColor.a"
        * pow(max(0.0, dot(reflect(-lightDirection, normalDirection), viewDirection)), frontMaterial.shininess);
    }
 
  gl_FragColor = vec4(ambientLighting + diffuseReflection + specularReflection, 1.0);
}

纹理和球体必须按照纹理球体教程中所述进行设置。

对于上述特定纹理图像，此着色器的有用修改是将漫反射材质颜色设置为 alpha 分量为 0 的深蓝色。

逐顶点光照的着色器代码

[编辑 | 编辑源代码]

如平滑镜面反射教程中所述，镜面反射通常无法使用逐顶点光照渲染得很好。但是，有时由于性能限制，别无选择。为了在光照纹理表面教程的着色器代码中包含光泽映射，应该使用以下代码替换片段着色器

varying vec3 diffuseColor;
    // the interpolated diffuse Phong lighting
varying vec3 specularColor;
    // the interpolated specular Phong lighting
varying vec4 texCoords;
    // the interpolated texture coordinates
uniform sampler2D mytexture;

void main(void)
{
    vec2 longitudeLatitude = vec2((atan(texCoords.y, texCoords.x) / 3.1415926 + 1.0) * 0.5,
                                  (asin(texCoords.z) / 3.1415926 + 0.5));
    // unusual processing of texture coordinates

    vec4 textureColor = 
        texture2D(mytexture, longitudeLatitude);
    gl_FragColor = vec4(diffuseColor * vec3(textureColor)
        + specularColor * (1.0 - textureColor.a), 1.0);
}

请注意，通常的光泽贴图需要乘以textureColor.a，而不是(1.0 - textureColor.a)。

总结

[编辑 | 编辑源代码]

恭喜！您完成了一个关于光泽映射的重要教程。我们已经了解了

  • 什么是光泽映射。
  • 如何为逐像素光照实现它。
  • 如何为逐顶点光照实现它。

进一步阅读

[编辑 | 编辑源代码]

如果您还想了解更多


< GLSL 编程/GLUT

除非另有说明，否则本页上的所有示例源代码都授予公共领域。
返回OpenGL 编程 - 光照部分 返回GLSL 编程 - GLUT 部分
检索自 "https://wikibooks.cn/w/index.php?title=GLSL_Programming/GLUT/Glossy_Textures&oldid=3679359"
华夏公益教科书