Cg 编程/Unity/纹理表面光照
本教程介绍了纹理表面的逐顶点光照。
它结合了“纹理球体”部分和“镜面高光”部分的着色器代码，使用纹理确定漫反射材质颜色来计算光照。如果你还没有阅读过这些部分，这是一个很好的机会来阅读它们。
在“纹理球体”部分，纹理颜色被用作片段着色器的输出。然而，纹理颜色也可以用作光照计算中的任何参数，特别是漫反射材质常数，它在“漫反射”部分中介绍。它出现在Phong 反射模型的漫反射部分
其中此公式与不同的材质常数一起使用，用于三种颜色组件：红色、绿色和蓝色。通过使用纹理来确定这些材质常数，它们可以在表面上变化。
与“镜面高光”部分中的逐顶点光照相比，这里的顶点着色器计算两个额外的输出颜色：diffuseColor 和 specularColor，它们使用语义 TEXCOORD1 和 TEXCOORD2。
参数 diffuseColor 在片段着色器中与纹理颜色相乘，而 specularColor 只是镜面项，不应与纹理颜色相乘。这很有道理，但出于历史原因（例如，较旧的图形硬件能力较弱），这有时被称为“分离镜面颜色”；事实上，Unity 的 ShaderLab 有一个名为“SeparateSpecular”的选项来激活或停用它。
请注意，包括一个属性 _Color，它（按组件方式）与 diffuseColor 的所有部分相乘；因此，它充当有用的颜色过滤器来对纹理颜色进行着色或阴影处理。此外，需要具有此名称的属性才能使回退着色器正常工作（另请参阅“漫反射”部分中关于回退着色器的讨论）。
Shader "Cg per-vertex lighting with texture" {
Properties {
_MainTex ("Texture For Diffuse Material Color", 2D) = "white" {}
_Color ("Overall Diffuse Color Filter", Color) = (1,1,1,1)
_SpecColor ("Specular Material Color", Color) = (1,1,1,1)
_Shininess ("Shininess", Float) = 10
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
// pass for ambient light and first light source
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform sampler2D _MainTex;
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 tex : TEXCOORD0;
float3 diffuseColor : TEXCOORD1;
float3 specularColor : TEXCOORD2;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float4x4 modelMatrixInverse = unity_WorldToObject;
float3 normalDirection = normalize(
mul(float4(input.normal, 0.0), modelMatrixInverse).xyz);
float3 viewDirection = normalize(_WorldSpaceCameraPos
- mul(modelMatrix, input.vertex).xyz);
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource = _WorldSpaceLightPos0.xyz
- mul(modelMatrix, input.vertex).xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
float3 ambientLighting =
UNITY_LIGHTMODEL_AMBIENT.rgb * _Color.rgb;
float3 diffuseReflection =
attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
output.diffuseColor = ambientLighting + diffuseReflection;
output.specularColor = specularReflection;
output.tex = input.texcoord;
output.pos = UnityObjectToClipPos(input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
return float4(input.specularColor +
input.diffuseColor * tex2D(_MainTex, input.tex.xy),
1.0);
}
ENDCG
}
Pass {
Tags { "LightMode" = "ForwardAdd" }
// pass for additional light sources
Blend One One // additive blending
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform sampler2D _MainTex;
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 tex : TEXCOORD0;
float3 diffuseColor : TEXCOORD1;
float3 specularColor : TEXCOORD2;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float4x4 modelMatrixInverse = unity_WorldToObject;
float3 normalDirection = normalize(
mul(float4(input.normal, 0.0), modelMatrixInverse).xyz);
float3 viewDirection = normalize(_WorldSpaceCameraPos
- mul(modelMatrix, input.vertex).xyz);
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource = _WorldSpaceLightPos0.xyz
- mul(modelMatrix, input.vertex).xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
float3 diffuseReflection =
attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
output.diffuseColor = diffuseReflection; // no ambient
output.specularColor = specularReflection;
output.tex = input.texcoord;
output.pos = UnityObjectToClipPos(input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
return float4(input.specularColor +
input.diffuseColor * tex2D(_MainTex, input.tex.xy),
1.0);
}
ENDCG
}
}
Fallback "Specular"
}
为了将纹理图像分配给此着色器，你应该按照“纹理球体”部分中讨论的步骤进行操作。
恭喜你，你已经到达了结尾。我们已经了解了
- 纹理和逐顶点光照通常如何组合。
- 什么是“分离镜面颜色”。
如果你还想了解更多
- 关于回退着色器或 Phong 反射模型的漫反射项，你应该阅读“漫反射”部分。
- 关于逐顶点光照或 Phong 反射模型的其余部分，即环境项和镜面项，你应该阅读“镜面高光”部分。
- 关于纹理的基本知识，你应该阅读“纹理球体”部分。
除非另有说明，否则本页面上的所有示例源代码均授予公有领域。