Cg 编程/Unity/半透明表面
本教程介绍半透明表面。
它是关于照明的几个教程之一，这些教程超出了 Phong 反射模型。但是，它基于每个像素的照明，使用 Phong 反射模型，如“光滑镜面高光”部分中所述。如果您还没有阅读该教程，您应该先阅读它。
Phong 反射模型没有考虑半透明性，即光线穿透材料的可能性。本教程介绍半透明表面，即允许光线从一个表面穿透到另一个表面的表面，例如纸张、衣服、塑料薄膜或叶子。
我们将区分两种光线传输：漫射半透明和前向散射半透明，它们分别对应于 Phong 反射模型中的漫射项和镜面项。漫射半透明是光的漫射传输，类似于 Phong 反射模型中的漫射反射项（参见“漫射反射”部分）：它仅取决于表面法线向量和光源方向的点积——除了我们使用负表面法线向量，因为光源位于背面，因此漫射半透明照明的方程式为
这是许多半透明表面的最常见照明，例如纸张和叶子。
一些半透明表面（例如塑料薄膜）几乎是透明的，并允许光线几乎直接地穿透表面，但具有一些前向散射；也就是说，人们可以通过表面看到光源，但图像有点模糊。这类似于 Phong 反射模型的镜面项（参见“镜面高光”部分以获取方程式），除了我们将反射光线方向R替换为负光线方向-L，并且指数现在对应于前向散射光线的锐度
当然，这种前向散射半透明模型并不准确，但它允许我们模拟这种效果并调整参数。
以下实现基于“光滑镜面高光”部分，它展示了使用 Phong 反射模型的每个像素照明。该实现允许渲染背面，并在这种情况下使用内置的 Cg 函数faceforward(n, v, ng)翻转表面法线向量，该函数在dot(v,ng)<0时返回n，否则返回-n。这种方法通常在轮廓线处失效，这会导致某些像素的照明不正确。改进后的版本将使用不同的通道和颜色来渲染正面和背面，如“双面光滑表面”部分中所示。
除了 Phong 反射模型的项之外，我们还使用此代码计算漫射半透明和前向散射半透明的照明
float3 diffuseTranslucency =
attenuation * _LightColor0.rgb
* _DiffuseTranslucentColor.rgb
* max(0.0, dot(lightDirection, -normalDirection));
float3 forwardTranslucency;
if (dot(normalDirection, lightDirection) > 0.0)
// light source on the wrong side?
{
forwardTranslucency = float3(0.0, 0.0, 0.0);
// no forward-scattered translucency
}
else // light source on the right side
{
forwardTranslucency = attenuation * _LightColor0.rgb
* _ForwardTranslucentColor.rgb * pow(max(0.0,
dot(-lightDirection, viewDirection)), _Sharpness);
}
完整的着色器代码定义了材料常量的着色器属性，并为具有添加剂混合的附加光源添加了另一个通道，但不包括环境光。
Shader "Cg translucent surfaces" {
Properties {
_Color ("Diffuse Material Color", Color) = (1,1,1,1)
_SpecColor ("Specular Material Color", Color) = (1,1,1,1)
_Shininess ("Shininess", Float) = 10
_DiffuseTranslucentColor ("Diffuse Translucent Color", Color)
= (1,1,1,1)
_ForwardTranslucentColor ("Forward Translucent Color", Color)
= (1,1,1,1)
_Sharpness ("Sharpness", Float) = 10
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
// pass for ambient light and first light source
Cull Off // show frontfaces and backfaces
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
uniform float4 _DiffuseTranslucentColor;
uniform float4 _ForwardTranslucentColor;
uniform float _Sharpness;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float4x4 modelMatrixInverse = unity_WorldToObject;
output.posWorld = mul(modelMatrix, input.vertex);
output.normalDir = normalize(
mul(float4(input.normal, 0.0), modelMatrixInverse).xyz);
output.pos = mul(UNITY_MATRIX_MVP, input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
float3 normalDirection = normalize(input.normalDir);
float3 viewDirection = normalize(
_WorldSpaceCameraPos - input.posWorld.xyz);
normalDirection = faceforward(normalDirection,
-viewDirection, normalDirection);
// flip normal if dot(-viewDirection, normalDirection)>0
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource =
_WorldSpaceLightPos0.xyz - input.posWorld.xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
// Computation of the Phong reflection model:
float3 ambientLighting =
UNITY_LIGHTMODEL_AMBIENT.rgb * _Color.rgb;
float3 diffuseReflection =
attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
// Computation of the translucent illumination:
float3 diffuseTranslucency =
attenuation * _LightColor0.rgb
* _DiffuseTranslucentColor.rgb
* max(0.0, dot(lightDirection, -normalDirection));
float3 forwardTranslucency;
if (dot(normalDirection, lightDirection) > 0.0)
// light source on the wrong side?
{
forwardTranslucency = float3(0.0, 0.0, 0.0);
// no forward-scattered translucency
}
else // light source on the right side
{
forwardTranslucency = attenuation * _LightColor0.rgb
* _ForwardTranslucentColor.rgb * pow(max(0.0,
dot(-lightDirection, viewDirection)), _Sharpness);
}
// Computation of the complete illumination:
return float4(ambientLighting
+ diffuseReflection + specularReflection
+ diffuseTranslucency + forwardTranslucency, 1.0);
}
ENDCG
}
Pass {
Tags { "LightMode" = "ForwardAdd" }
// pass for additional light sources
Cull Off
Blend One One // additive blending
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
uniform float4 _DiffuseTranslucentColor;
uniform float4 _ForwardTranslucentColor;
uniform float _Sharpness;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float4x4 modelMatrixInverse = unity_WorldToObject;
output.posWorld = mul(modelMatrix, input.vertex);
output.normalDir = normalize(
mul(float4(input.normal, 0.0), modelMatrixInverse).xyz);
output.pos = mul(UNITY_MATRIX_MVP, input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
float3 normalDirection = normalize(input.normalDir);
float3 viewDirection = normalize(
_WorldSpaceCameraPos - input.posWorld.xyz);
normalDirection = faceforward(normalDirection,
-viewDirection, normalDirection);
// flip normal if dot(-viewDirection, normalDirection)>0
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource =
_WorldSpaceLightPos0.xyz - input.posWorld.xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
// Computation of the Phong reflection model:
float3 diffuseReflection =
attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
// Computation of the translucent illumination:
float3 diffuseTranslucency =
attenuation * _LightColor0.rgb
* _DiffuseTranslucentColor.rgb
* max(0.0, dot(lightDirection, -normalDirection));
float3 forwardTranslucency;
if (dot(normalDirection, lightDirection) > 0.0)
// light source on the wrong side?
{
forwardTranslucency = float3(0.0, 0.0, 0.0);
// no forward-scattered translucency
}
else // light source on the right side
{
forwardTranslucency = attenuation * _LightColor0.rgb
* _ForwardTranslucentColor.rgb * pow(max(0.0,
dot(-lightDirection, viewDirection)), _Sharpness);
}
// Computation of the complete illumination:
return float4(diffuseReflection + specularReflection
+ diffuseTranslucency + forwardTranslucency, 1.0);
}
ENDCG
}
}
}
恭喜！您完成了本关于半透明表面的教程，它们非常常见，但无法通过 Phong 反射模型来建模。我们涵盖了
- 什么是半透明表面。
- 哪些形式的半透明性最常见（漫射半透明和前向散射半透明）。
- 如何实现漫射和前向散射半透明。
如果您还想了解更多
- 关于 Phong 反射模型的漫射项，您应该阅读“漫射反射”部分。
- 关于 Phong 反射模型的环境项或镜面项，您应该阅读“镜面高光”部分。
- 关于使用 Phong 反射模型的每个像素照明，您应该阅读“光滑镜面高光”部分。
- 关于双面表面的每个像素照明，您应该阅读“双面光滑表面”部分。
除非另有说明，否则本页上的所有示例源代码均属于公有领域。