Cg 编程/Unity/光泽纹理
本教程涵盖 **部分光泽、纹理表面的逐像素光照**。
它结合了 “纹理球体”部分 和 “平滑镜面反射”部分 的着色器代码，以计算逐像素光照，使用纹理的 RGB 分量来确定漫反射材料颜色，以及使用相同纹理的 A 分量来确定镜面反射的强度。如果您还没有阅读过这些部分，现在是一个非常好的机会去阅读它们。
在 “光照纹理表面”部分 中，漫反射的材料常数由纹理图像的 RGB 分量决定。这里我们扩展了这种技术，并通过相同纹理图像的 A (alpha) 分量来确定镜面反射的强度。仅使用一个纹理提供了显著的性能优势，特别是由于在某些情况下，RGBA 纹理查找与 RGB 纹理查找一样昂贵。
如果纹理图像的“光泽”（即镜面反射的强度）编码在 RGBA 纹理图像的 A (alpha) 分量中，我们可以简单地将镜面反射的材料常数 与纹理图像的 alpha 分量相乘。 在 “镜面反射”部分 中引入，并出现在 Phong 反射模型的镜面反射项中
如果与纹理图像的 alpha 分量相乘，则该项达到最大值（即表面光泽），其中 alpha 为 1，并且它为 0（即表面完全不光泽），其中 alpha 为 0。
着色器代码是 “平滑镜面反射”部分 中的逐像素光照和 “纹理球体”部分 中的纹理的组合。与 “光照纹理表面”部分 类似，textureColor 中纹理颜色的 RGB 分量乘以漫反射材料颜色 _Color。
在左侧的特定纹理图像中，水的 alpha 分量为 0，陆地的 alpha 分量为 1。但是，应该是水具有光泽，而陆地没有光泽。因此，对于这个特定的图像，我们应该将镜面材料颜色乘以 (1.0 - textureColor.a)。另一方面，普通的 gloss map 需要乘以 textureColor.a。（请注意，对着色器程序进行这种修改是多么容易。）
Shader "Cg per-pixel lighting with texture" {
Properties {
_MainTex ("RGBA Texture For Material Color", 2D) = "white" {}
_Color ("Diffuse Material Color", Color) = (1,1,1,1)
_SpecColor ("Specular Material Color", Color) = (1,1,1,1)
_Shininess ("Shininess", Float) = 10
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
// pass for ambient light and first light source
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform sampler2D _MainTex;
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
float4 tex : TEXCOORD2;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float4x4 modelMatrixInverse = unity_WorldToObject;
output.posWorld = mul(modelMatrix, input.vertex);
output.normalDir = normalize(
mul(float4(input.normal, 0.0), modelMatrixInverse).xyz);
output.tex = input.texcoord;
output.pos = UnityObjectToClipPos(input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
float3 normalDirection = normalize(input.normalDir);
float3 viewDirection = normalize(
_WorldSpaceCameraPos - input.posWorld.xyz);
float3 lightDirection;
float attenuation;
float4 textureColor = tex2D(_MainTex, input.tex.xy);
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection =
normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource =
_WorldSpaceLightPos0.xyz - input.posWorld.xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
float3 ambientLighting = textureColor.rgb
* UNITY_LIGHTMODEL_AMBIENT.rgb * _Color.rgb;
float3 diffuseReflection = textureColor.rgb
* attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * (1.0 - textureColor.a)
// for usual gloss maps: "... * textureColor.a"
* pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
return float4(ambientLighting + diffuseReflection
+ specularReflection, 1.0);
}
ENDCG
}
Pass {
Tags { "LightMode" = "ForwardAdd" }
// pass for additional light sources
Blend One One // additive blending
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform sampler2D _MainTex;
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
float4 tex : TEXCOORD2;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float4x4 modelMatrixInverse = unity_WorldToObject;
output.posWorld = mul(modelMatrix, input.vertex);
output.normalDir = normalize(
mul(float4(input.normal, 0.0), modelMatrixInverse).xyz);
output.tex = input.texcoord;
output.pos = UnityObjectToClipPos(input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
float3 normalDirection = normalize(input.normalDir);
float3 viewDirection = normalize(
_WorldSpaceCameraPos - input.posWorld.xyz);
float3 lightDirection;
float attenuation;
float4 textureColor = tex2D(_MainTex, input.tex.xy);
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection =
normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource =
_WorldSpaceLightPos0.xyz - input.posWorld.xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
float3 diffuseReflection = textureColor.rgb
* attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb
* _SpecColor.rgb * (1.0 - textureColor.a)
// for usual gloss maps: "... * textureColor.a"
* pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
return float4(diffuseReflection
+ specularReflection, 1.0);
// no ambient lighting in this pass
}
ENDCG
}
}
Fallback "Specular"
}
对上述特定纹理图像进行的有用修改是，在 alpha 分量为 0 的地方将漫反射材料颜色设置为深蓝色。
如 “平滑镜面反射”部分 中所述，镜面反射通常不能很好地使用逐顶点光照渲染。但是，有时由于性能限制别无选择。为了在 “光照纹理表面”部分 的着色器代码中包含 gloss map，两个通道的片段着色器都应该用以下代码替换
float4 frag(vertexOutput input) : COLOR
{
float4 textureColor = tex2D(_MainTex, input.tex.xy);
return float4(input.specularColor * (1.0 - textureColor.a) +
input.diffuseColor * textureColor.rgb, 1.0);
}
请注意，普通的 gloss map 需要乘以 textureColor.a 而不是 (1.0 - textureColor.a)。
恭喜！您完成了关于 gloss map 的重要教程。我们已经了解了
- 什么是 gloss map。
- 如何为逐像素光照实现它。
- 如何为逐顶点光照实现它。
如果您还想了解更多
- 关于逐像素光照（不使用纹理），您应该阅读 “平滑镜面反射”部分.
- 关于纹理，您应该阅读 “纹理球体”部分.
- 关于使用纹理的逐顶点光照，您应该阅读 “光照纹理表面”部分.
除非另有说明，本页上的所有示例源代码均授予公有领域。