Cg 编程/Unity/轮廓上的镜面高光
本教程涵盖了镜面高光的菲涅尔系数。
它是关于光照的几个教程之一，它超出了Phong 反射模型。然而，它基于“镜面高光”部分（针对每个顶点的光照）和“平滑镜面高光”部分（针对每个像素的光照）中描述的Phong 反射模型的光照。如果您还没有阅读这些教程，请先阅读它们。
许多材料（例如哑光纸）在光线掠过表面时会显示强烈的镜面反射；即，当背光从与观察者相反的方向反射时，如左侧照片所示。菲涅尔系数解释了某些材料的这种强反射。当然，还有其他导致明亮轮廓的原因，例如半透明头发或织物（参见“半透明表面”部分）。
有趣的是，这种效果通常很难看到，因为当轮廓的背景非常明亮时最有可能出现。然而，在这种情况下，明亮的轮廓只会融入背景，因此几乎不可察觉。
菲涅尔系数 描述了非导电材料在波长为 的非偏振光时的镜面反射率。Schlick 近似为
其中V是指向观察者的归一化方向，H是归一化的半向量：H = (V + L) / |V + L|，其中L是指向光源的归一化方向。 是H·V = 1时的反射率，即当指向光源的方向、指向观察者的方向和半向量都相同时。另一方面， 对于H·V = 0变为1，即当半向量与指向观察者的方向正交时，这意味着指向光源的方向与指向观察者的方向相反（即掠射光反射的情况）。事实上， 在这种情况下与波长无关，材料的行为就像一个完美的镜子。
使用内置的Cg函数lerp(x,y,w) = x*(1-w) + y*w，我们可以将Schlick近似改写为
这可能会稍微高效一些，至少在某些 GPU 上。我们将通过允许不同的 值来考虑对波长的依赖性；也就是说，我们将它视为 RGB 向量。事实上，我们将其与来自“镜面高光”部分的常量材质颜色 相识别。换句话说，菲涅耳系数增加了材质颜色 对视角方向和半向量之间角度的依赖性。因此，我们在任何镜面反射计算中用施里克近似（使用）替换常量材质颜色。
例如，我们在 Phong 反射模型中关于镜面项的方程是（参见“镜面高光”部分）
用施里克近似（使用）替换菲涅耳系数的，得到
该实现基于来自“平滑镜面高光”部分的着色器代码。它只是计算半向量，并包括菲涅耳系数的近似值
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
float3 halfwayDirection =
normalize(lightDirection + viewDirection);
float w = pow(1.0 - max(0.0,
dot(halfwayDirection, viewDirection)), 5.0);
specularReflection = attenuation * _LightColor0.rgb
* lerp(_SpecColor.rgb, float3(1.0, 1.0, 1.0), w)
* pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
将上面代码片段放入来自“Smooth Specular Highlights”部分的完整着色器中，将得到以下着色器。
Shader "Cg Fresnel highlights" {
Properties {
_Color ("Diffuse Material Color", Color) = (1,1,1,1)
_SpecColor ("Specular Material Color", Color) = (1,1,1,1)
_Shininess ("Shininess", Float) = 10
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
// pass for ambient light and first light source
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float3x3 modelMatrixInverse = unity_WorldToObject;
output.posWorld = mul(modelMatrix, input.vertex);
output.normalDir = normalize(mul(input.normal, modelMatrixInverse));
output.pos = mul(UNITY_MATRIX_MVP, input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
float3 normalDirection = normalize(input.normalDir);
float3 viewDirection = normalize(
_WorldSpaceCameraPos - input.posWorld.xyz);
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource =
_WorldSpaceLightPos0.xyz - input.posWorld.xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
float3 ambientLighting =
UNITY_LIGHTMODEL_AMBIENT.rgb * _Color.rgb;
float3 diffuseReflection =
attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
float3 halfwayDirection =
normalize(lightDirection + viewDirection);
float w = pow(1.0 - max(0.0,
dot(halfwayDirection, viewDirection)), 5.0);
specularReflection = attenuation * _LightColor0.rgb
* lerp(_SpecColor.rgb, float3(1.0, 1.0, 1.0), w)
* pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
return float4(ambientLighting
+ diffuseReflection + specularReflection, 1.0);
}
ENDCG
}
Pass {
Tags { "LightMode" = "ForwardAdd" }
// pass for additional light sources
Blend One One // additive blending
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
uniform float4 _LightColor0;
// color of light source (from "Lighting.cginc")
// User-specified properties
uniform float4 _Color;
uniform float4 _SpecColor;
uniform float _Shininess;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
};
vertexOutput vert(vertexInput input)
{
vertexOutput output;
float4x4 modelMatrix = unity_ObjectToWorld;
float4x4 modelMatrixInverse = unity_WorldToObject;
output.posWorld = mul(modelMatrix, input.vertex);
output.normalDir = normalize(
mul(float4(input.normal, 0.0), modelMatrixInverse).xyz);
output.pos = mul(UNITY_MATRIX_MVP, input.vertex);
return output;
}
float4 frag(vertexOutput input) : COLOR
{
float3 normalDirection = normalize(input.normalDir);
float3 viewDirection = normalize(
_WorldSpaceCameraPos - input.posWorld.xyz);
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource =
_WorldSpaceLightPos0.xyz - input.posWorld.xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
float3 diffuseReflection =
attenuation * _LightColor0.rgb * _Color.rgb
* max(0.0, dot(normalDirection, lightDirection));
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0)
// light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0);
// no specular reflection
}
else // light source on the right side
{
float3 halfwayDirection =
normalize(lightDirection + viewDirection);
float w = pow(1.0 - max(0.0,
dot(halfwayDirection, viewDirection)), 5.0);
specularReflection = attenuation * _LightColor0.rgb
* lerp(_SpecColor.rgb, float3(1.0, 1.0, 1.0), w)
* pow(max(0.0, dot(
reflect(-lightDirection, normalDirection),
viewDirection)), _Shininess);
}
return float4(diffuseReflection
+ specularReflection, 1.0);
}
ENDCG
}
}
Fallback "Specular"
}
艺术控制
[edit | edit source]对上面实现的一个有用修改是将幂5.0替换为用户指定的着色器属性。这将为CG艺术家提供一个选项，根据他们的艺术需求夸大或衰减菲涅尔因子的影响。
半透明表面的影响
[edit | edit source]除了影响镜面高光外，菲涅尔因子还应影响半透明表面的不透明度。事实上，菲涅尔因子描述了表面如何对于掠射光线变得更加反射，这意味着更少的入射光被吸收、折射或透射，即透明度降低，因此不透明度增加。为此，可以使用表面法线向量N代替半程向量H来计算菲涅尔因子，并且半透明表面的不透明度可以从用户指定的值（在表面法线方向观看）增加到 1（与波长无关），公式为
.
在“Silhouette Enhancement”部分中，不透明度被认为是由于光线穿过一层半透明材料而导致的衰减。这种不透明度应该与由于反射率增加而产生的不透明度相结合：总不透明度是 1 减去总透明度，它是由于衰减而产生的透明度（它是 1 减去）和由于菲涅尔因子而产生的透明度（它是 1 减去）的乘积，即
是如上计算得到的透明度，而 是在 “轮廓增强” 部分计算得到的透明度。对于平行于表面法向量的视角方向， 和 可以由用户指定。然后，该方程确定了 的法线方向，实际上，它确定了所有常数，因此可以计算所有视角方向的 。请注意，漫反射或镜面反射都不应乘以透明度 ，因为镜面反射已经乘以菲涅尔系数，漫反射应该只乘以由于衰减造成的透明度 。
总结
[edit | edit source]恭喜您完成了本教程！我们已经了解了：
- 什么是菲涅尔系数。
- 什么是菲涅尔系数的施里克近似。
- 如何实现镜面高光的施里克近似。
- 如何为实现添加更多艺术控制。
- 如何使用菲涅尔系数来呈现半透明表面。
进一步阅读
[edit | edit source]如果您想了解更多关于以下内容：
- 使用 Phong 反射模型进行光照，请阅读 “镜面高光” 部分。
- 关于逐像素光照（即 Phong 着色），请阅读 “平滑镜面高光” 部分。
- 关于施里克近似，请阅读 Christophe Schlick 发表的文章“An inexpensive BRDF model for physically-based rendering”，计算机图形论坛，第 13 卷，第 3 期：233—246，1994 年。或者您可以阅读 Randi Rost 等人撰写的《OpenGL 着色语言》（第 3 版，2009 年由 Addison-Wesley 出版）的第 14.1 章，或 Wolfgang Engel、Jack Hoxley、Ralf Kornmann、Niko Suni 和 Jason Zink 撰写的《编程顶点、几何体和像素着色器》（第 2 版，2008 年）的光照章节中的第 5 章（可在 网上 获得）。